#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['30.06.1815':'30.06.2015']
set xtics '01.01.1000', 60 * 60 * 24 * 365.25 * 25
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5          # Unterteilung der Skalierung
set xtics nomirror    # Nur unten Skalieren
set format x '%Y'     # Beschriftungsformat JJJJ


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl'
set yrange [0:]
set ytics 2500
set mytics 5
set ytics nomirror
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f" # Ausgabeformat


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe (zum Anlegen der Datei 'daten.scv' siehe unten)
plot '-' using 1:($2) with filledcurves below x1 lt rgb 'dark-blue' lw 2


#
# Quelle:
# https://de.wikipedia.org/wiki/Schifferstadt#Bev.C3.B6lkerungsentwicklung
#
30.06.1815;1836
30.06.1835;2994
30.06.1871;3995
30.06.1905;7505
30.06.1939;11315
30.06.1950;13242
#
30.06.1961;15636
30.06.1970;17148
30.06.1987;17322
30.06.1997;18955
30.06.2005;19242
30.06.2015;19701
EOF